gtk_tests = [
  # testname, optional extra sources
  ['animated-resizing', ['frame-stats.c', 'variable.c']],
  ['animated-revealing', ['frame-stats.c', 'variable.c']],
  ['scrolling-performance', ['frame-stats.c', 'variable.c']],
  ['blur-performance', ['../gtk/gtkcairoblur.c']],
  ['flicker'],
  ['gdkgears', ['gtkgears.c']],
  ['listmodel'],
  ['motion-compression'],
  ['styleexamples'],
  ['overlayscroll'],
  ['print-editor'],
  ['simple'],
  ['subsurface'],
  ['syncscroll'],
  ['testaccel'],
  ['testactionbar'],
  ['testactions'],
  ['testadjustsize'],
  ['testanimation'],
  ['testappchooserbutton'],
  ['testappchooser'],
  ['testassistant'],
  ['testbaseline'],
  ['testbbox'],
  ['testbox'],
  ['testboxcss'],
  ['testbuttons'],
  ['testcairo'],
  ['testcalendar'],
  ['testcellarea'],
  ['testcellrenderertext'],
  ['testclipboard'],
  ['testcolorchooser'],
  ['testcombo'],
  ['testcombochange'],
  ['testdialog'],
  ['testdnd'],
  ['testellipsise'],
  ['testemblems'],
  ['testentrycompletion'],
  ['testentryicons'],
  ['testexpand'],
  ['testexpander'],
  ['testfilechooserbutton'],
  ['testfilechooser'],
  ['testflowbox'],
  ['testfontchooser'],
  ['testfontoptions'],
  ['testfontselection'],
  ['testfontselectiondialog'],
  ['testframe'],
  ['testfullscreen'],
  ['testgeometry'],
  ['testgiconpixbuf'],
  ['testglblending', ['gtkgears.c']],
  ['testgmenu'],
  ['testgrid'],
  ['testgrouping'],
  ['testgtk'],
  ['testheaderbar'],
  ['testheightforwidth'],
  ['testicontheme'],
  ['testiconview'],
  ['testimage'],
  ['testinput'],
  ['testkineticscrolling'],
  ['testlevelbar'],
  ['testlist'],
  ['testlockbutton'],
  ['testlogout'],
  ['testmenubutton'],
  ['testmerge'],
  ['testmountoperation'],
  ['testmultidisplay'],
  ['testnoscreen'],
  ['testnotebookdnd'],
  ['testnouiprint'],
  ['testnumerableicon'],
  ['testoffscreen', ['gtkoffscreenbox.c']],
  ['testoffscreenwindow'],
  ['testorientable'],
  ['testoverlay'],
  ['testoverlaystyleclass'],
  ['testpopover'],
  ['testpopupat'],
  ['testpopup'],
  ['testprint', ['testprintfileoperation.c']],
  ['testrecentchooser'],
  ['testrecentchoosermenu'],
  ['testrevealer'],
  ['testrichtext'],
  ['testscale'],
  ['testscrolledge'],
  ['testscrolledwindow'],
  ['testselection'],
  ['testselectionmode'],
  ['testsensitive'],
  ['testspinbutton'],
  ['testsplitheaders'],
  ['teststack'],
  ['teststatusicon'],
  ['teststockbuttonmenu'],
  ['testswitch'],
  ['testtextview'],
  ['testtitlebar'],
  ['testtoolbar'],
  ['testtooltips'],
  ['testtoplevelembed'],
  ['testtreechanging'],
  ['testtreecolumns'],
  ['testtreecolumnsizing'],
  ['testtreednd'],
  ['testtreeedit'],
  ['testtreeflow'],
  ['testtreefocus'],
  ['testtreemenu'],
  ['testtreemodel'],
  ['testtreepos'],
  ['testtreesort'],
  ['testtreeview'],
  ['testverticalcells'],
  ['testvolumebutton'],
  ['testwindows'],
  ['testwindowsize'],
  ['testxinerama'],
  ['treestoretest'],
  ['video-timer', ['variable.c']],
]

# Conditionally compiled tests
if x11_enabled
  gtk_tests += [
    ['testsocket', ['testsocket_common.c']],
    ['testsocket_child', ['testsocket_common.c']],
  ]
endif

if os_linux
  gtk_tests += [['testfontchooserdialog']]
endif

# Pass the source dir here so programs can change into the source directory
# and find .ui files and .png files and such that they load at runtime
test_args = ['-DGTK_SRCDIR="@0@"'.format(meson.current_source_dir())]

foreach t: gtk_tests
  test_name = t.get(0)
  test_srcs = ['@0@.c'.format(test_name), t.get(1, [])]
  executable(test_name, test_srcs,
             c_args: test_args,
             dependencies: [libgtk_dep, libm])
endforeach

subdir('visuals')
